Actually there were several changes required for your script. My guess is that this particular script was made for a particular type of dataset because several items are hard-coded , and other scripts were used in your group for other types. Along with changes in Philips export tool, even more changes were needed.

In any case, this is a modification of your script with the principal changes in the x,y resolution, adding a "TR" for volumes, byte-swapping, switching the time-slice order (as you found), reversing orientation information. You'll have to verify left-right with the fiducial marker information in the images. I'll take a look at modifying the 3dPAR2AFNI script too, but this should work for you for now.

# PAR_to4d.csh oufile(afni) infile(PAR/REC)
#
# do not give filename extensions
#
set parFile = $2.PAR
set recFile = $2.REC

set NT = `cat $parFile | grep dynamics | cut -d: -f2 | sed 's/^[ \t]*//' | tr -d "\r"`
set NP = `cat $parFile | grep phases | cut -d: -f2 | sed 's/^[ \t]*//' | tr -d "\r"`
set NS = `cat $parFile | grep locations | cut -d: -f2 | sed 's/^[ \t]*//' | tr -d "\r"`
set XFOV = `cat $parFile | grep FOV | cut -d: -f2 | sed 's/^[ \t]*//' | tr -d "\r" | cut -d' ' -f3`
set ZFOV = `cat $parFile | grep FOV | cut -d: -f2 | sed 's/^[ \t]*//' | tr -d "\r" | cut -d' ' -f5`

# Get resolution from line describing last slice in volume at end of file
set NX = `cat $parFile | tail -3 | head -1 | sed 's/^ *//g' | awk '{print$10}'`
set NY = `cat $parFile | tail -3 | head -1 | sed 's/^ *//g' | awk '{print$11}'`
set TR = `cat $parFile | grep "Repetition time" | cut -d: -f2 | sed 's/^[ \t]*//' | tr -d "\r"`
#set NX = `cat $parFile | head -92 | tail -1 | sed 's/^ *//g' | sed 's/ */ /g' | cut -d' ' -f10`
@ N2Dslices = ${NS} * ${NT} * ${NP}

set target = "3D:0:0:"${NX}":"${NY}":"${N2Dslices}":"${recFile}
set temporal = "time:zt "${NS}" "${NT}" ${TR}ms simult"
echo "Converting -${temporal} $target"

to3d -prefix $1 \
-in:1\
-skip_outliers \
-2swap \
-xFOV ${XFOV}I-S\
-yFOV ${XFOV}R-L\
-zFOV ${ZFOV}P-A\
-$temporal \
$target