Hi, Momo-

Thanks. The translation part of that is (\delta x, \delta y, \delta z) = (6.93706, 12.3146, -6.46164), which doesn't look large to my human-dataset-centric eyes, but I'm guessing in a mouse dataset might be quite large.

What is the output of:

3dinfo -ad3 -n4 -prefix DSET_SOURCE DSET_TEMPLATE

where the DSET_* files are your mouse anatomical being input to @animal_warper and the reference template you are using there?

To check the initial overlap and relative alignment, could you please run this script, where you have to provide the particular file names for the DSET_SOURCE and DSET_TEMPLATE here, and then attach the output "img_overlap_FINAL.jpg":

#!/bin/tcsh

set dset_src  =  [input mouse source dataset here]
set dset_ref  =  [input mouse reference template here]

set opref_img = img_overlap

# ------------------------------------------------------------------------

set dset_cp_ref = __TMP_COPY_REF.nii.gz

# copy the ref and make sure the ref and src have the same space, to
# overlay for visualizing
3dcopy                                     \
    -overwrite                             \
    "${dset_ref}"                          \
    ${dset_cp_ref}

3drefit -space `3dinfo -space "${dset_src}"` "${dset_cp_ref}"

# ------- make image along each viewplane
@chauffeur_afni                        \
    -ulay  "${dset_src}"               \
    -olay  "${dset_cp_ref}"            \
    -pbar_posonly                      \
    -cbar Reds_and_Blues               \
    -set_subbricks 0 0 0               \
    -opacity 5                         \
    -prefix   "${opref_img}"           \
    -montx 1 -monty 1                  \
    -set_xhairs ON                     \
    -label_mode 1 -label_size 3        \
    -do_clean 

# glue separate images together
2dcat                                  \
    -gap 5                             \
    -gap_col 128 128 128               \
    -nx 3 -ny 1                        \
    -prefix "${opref_img}_FINAL.jpg"   \
    "${opref_img}".*.png

echo ""
echo "++ DONE.  Please check out this image for relative alignment/overlap:"
echo "     ${opref_img}_FINAL.jpg"
echo ""

# ... and you can delete the __TMP_COPY_REF.nii.gz file, if you want

exit 0

This will make an image like the attached (run on human datasets). The underlay (grayscale) dset is your subject/source, and the overlay (colorized) dset is the reference template. In the attached case, there is not a very large difference between the two dsets, which is good for starting alignment.

--pt